summaryrefslogtreecommitdiff
path: root/lib/bio/bio.myr
blob: eb550694e7254a7a5ca943bf0df68954ccb22ca2 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
use std
use "types"

pkg bio =
	/* creation */
	const mk	: (mode : mode, vt : vtab	-> file#)
	const close	: (f : file# -> bool)
	const free	: (f : file# -> void)

	/* basic i/o. Returns sub-buffer when applicable. */
	const write	: (f : file#, src : byte[:]	-> std.result(std.size, err))
	const read	: (f : file#, dst : byte[:]	-> std.result(byte[:], err))
	const flush	: (f : file# -> bool)

	/* seeking */
	const seek	: (f : file#, off : std.off -> std.result(std.off, err))

	/* single unit operations */
	const putb	: (f : file#, b : byte	-> std.result(std.size, err))
	const putc	: (f : file#, c : char	-> std.result(std.size, err))
	const getb	: (f : file# -> std.result(byte, err))
	const getc	: (f : file# -> std.result(char, err))

	/* peeking */
	const peekb	: (f : file# -> std.result(byte, err))
	const peekc	: (f : file# -> std.result(char, err))

	/* delimited read; returns freshly allocated buffer. */
	const readln	: (f : file#	-> std.result(byte[:], err))
	const readto	: (f : file#, delim : byte[:]	-> std.result(byte[:], err))
	const skipto	: (f : file#, delim : byte[:]	-> bool)
	const skipspace	: (f : file# -> bool)

	/* formatted i/o */
	const put	: (f : file#, fmt : byte[:], args : ... -> std.result(std.size, err))
	const putv	: (f : file#, fmt : byte[:], ap : std.valist# -> std.result(std.size, err))

	/* pkg funcs */
	pkglocal const ensureread	: (f : file#, n : std.size -> std.result(std.size, err))
	pkglocal const ensurewrite	: (f : file#, n : std.size -> std.result(std.size, err))

	impl disposable file#
;;

const Bufsz = 16*std.KiB
const Small = 512

impl disposable file# =
	__dispose__ = {f
		close(f)
	}
;;

/* Creates a file from an fd, opened in the given mode. */
const mk = {mode, vt
	var f

	f = std.alloc()

	f.mode = mode
	f.read = std.fndup(vt.read)
	f.write = std.fndup(vt.write)
	f.seek = std.fndup(vt.seek)
	f.close = std.fndup(vt.close)

	f.lasterr = 0
	if mode & Rd != 0
		f.rbuf = std.slalloc(Bufsz)
		f.rstart = 0
		f.rend = 0
	;;
	if mode & Wr != 0
		f.wbuf = std.slalloc(Bufsz)
		f.wend = 0
	;;
	-> f
}

/* closes a file, flushing it to the output fd */
const close = {f
	var ok

	ok = flush(f)
	ok = ok && f.close()
	_free(f)
	-> ok
}

const free = {f
	flush(f)
	_free(f)
}

const _free = {f
	if f.mode & Rd != 0
		std.slfree(f.rbuf)
	;;

	if f.mode & Wr != 0
		std.slfree(f.wbuf)
	;;
	std.fnfree(f.read)
	std.fnfree(f.write)
	std.fnfree(f.seek)
	std.fnfree(f.close)
	std.free(f)
}

/* 
writes to as much from `src` as possible to a file,
returning the number of bytes written.
*/
const write = {f, src
	std.assert(f.mode & Wr != 0, "File is not in write mode")
	/*
	Tack small writes onto the buffer end. Big ones
	flush the buffer and then go right to kernel.
	*/
	if src.len <= (f.wbuf.len - f.wend)
		std.slcp(f.wbuf[f.wend:f.wend+src.len], src)
		f.wend += src.len
		-> `std.Ok src.len
	else
		flush(f)
		-> writebuf(f, src)
	;;
}

/*
reads as much into 'dst' as possible, up to the size of 'dst',
returning the number of bytes read.
*/
const read = {f, dst
	var count, cap : std.size
	var d : byte[:]

	/* Clear the error state so we can retry */
	if f.lasterr != 0
		-> `std.Err geterr(f)
	;;

	/*
	a zero byte read always succeeds, reading 0 bytes; since
	there are an infinite number of zero byte reads you can do
	from anywhere in the file, including the end, this is not
	an EOF condition.
	*/
	if dst.len == 0
		-> `std.Ok dst
	;;
	std.assert(f.mode & Rd != 0, "File is not in read mode")
	/* 
	small reads should try to fill, so we don't have to make a
	syscall for every read
	*/
	cap = f.rend - f.rstart
	if dst.len < Small && cap < dst.len
		fill(f, dst.len)
	;;
	/* Read as much as we can from the buffer */
	count = std.min(dst.len, f.rend - f.rstart)
	std.slcp(dst[:count], f.rbuf[f.rstart:f.rstart+count])
	f.rstart += count

	/* if we drained the buffer, reset it */
	if f.rstart == f.rend
		f.rstart = 0
		f.rend = 0
	;;

	/* Read the rest directly from the fd */
	d = dst[count:]
	while d.len > 0
		match f.read(d)
		| `std.Ok 0:
			break
		| `std.Ok n:
			count += n
			d = d[n:]
		| `std.Err err:
			if count == 0
				-> `std.Err errtype(err)
			else
				f.lasterr = err
			;;
			break
		;;
	;;
	if count == 0
		-> `std.Err `Eof
	else
		-> `std.Ok dst[:count]
	;;
}

/* flushes f out to the backing fd */
const flush = {f
	var ret

	ret = true
	if f.mode & Wr != 0
		match writebuf(f, f.wbuf[:f.wend])
		| `std.Ok n: ret = (n == f.wend)
		| _:	ret = false
		;;
	;;
	f.wend = 0
	-> ret
}

const seek = {f, off
	flush(f)
	f.rstart = f.rend = 0
	match f.seek(off)
	| `std.Ok ret:	-> `std.Ok ret
	| `std.Err e:	-> `std.Err errtype(e)
	;;
}

/* writes a single byte to the output stream */
const putb = {f, b
	match ensurewrite(f, 1)
	| `std.Err e:	-> `std.Err e
	| `std.Ok n:
		f.wbuf[f.wend++] = b
		-> `std.Ok 1
	;;
}

/* writes a single character to the output stream, encoded in utf8 */
const putc = {f, c
	var sz
	
	sz = std.charlen(c)
	match ensurewrite(f, sz)
	| `std.Err e:	-> `std.Err e
	| `std.Ok n:
		std.encode(f.wbuf[f.wend:], c)
		f.wend += sz
		-> `std.Ok sz
	;;
}

/* reads a single byte from the input stream */
const getb = {f
	match ensureread(f, 1)
	| `std.Err e:	-> `std.Err e
	| `std.Ok n:
		-> `std.Ok f.rbuf[f.rstart++]
	;;
}

/* reads a single character from the input stream, encoded in utf8 */
const getc = {f
	var c

	match ensurecodepoint(f)
	| `std.Err e:	-> `std.Err e
	| `std.Ok n:
		c = std.decode(f.rbuf[f.rstart:f.rend])
		f.rstart += std.charlen(c)
		-> `std.Ok c
	;;
}

/* ensures we have enough to read a single codepoint in the buffer */
const ensurecodepoint = {f
	var b
	var len

	match ensureread(f, 1)
	| `std.Err e:	-> `std.Err e
	| `std.Ok n:
		b = f.rbuf[f.rstart]
		if b & 0x80 == 0	/* 0b0xxx_xxxx */
			len = 1
		elif b & 0xe0 == 0xc0	/* 0b110x_xxxx */
			len = 2
		elif b & 0xf0 == 0xe0 	/* 0b1110_xxxx */
			len = 3
		elif b & 0xf8 == 0xf0 	/* 0b1111_0xxx */
			len = 4
		else
			len = 1		/* invalid unicode char */
		;;
		-> ensureread(f, len)
	;;
}

/*
  writes a single integer-like value to the output stream, in
  little endian format
*/
generic putle = {f, v : @a :: numeric,integral @a
	for var i = 0; i < sizeof(@a); i++
		putb(f, (v & 0xff : byte))
		v >>= 8
	;;
	-> sizeof(@a)
}

/*
  writes a single integer-like value to the output stream, in
  big endian format
*/
generic putbe = {f, v : @a :: numeric,integral @a
	for var i = sizeof(@a); i != 0; i--
		putb(f, ((v >> ((i-1)*8)) & 0xff : byte))
	;;
	-> sizeof(@a)
}


/* peeks a single byte from an input stream */
const peekb = {f
	match ensureread(f, 1)
	| `std.Err e:	-> `std.Err e
	| `std.Ok n:
		-> `std.Ok f.rbuf[f.rstart]
	;;
}

/* peeks a single character from a utf8 encoded input stream */
const peekc = {f
	match ensurecodepoint(f)
	| `std.Err e:	-> `std.Err e
	| `std.Ok n:
		-> `std.Ok std.decode(f.rbuf[f.rstart:f.rend])
	;;
}

/*
  reads up to a single character delimiter. drops the delimiter
  from the input stream. EOF always counts as a delimiter.
  
  Eg, with the input "foo,bar\n"

  	bio.readto(f, ',')	-> "foo"
  	bio.readto(f, ',')	-> "bar\n"
*/
const readto = {f, delim
	-> readdelim(f, delim, false)
}

/* same as readto, but drops the read data. */
const skipto = {f, delim
	match readdelim(f, delim, true)
	| `std.Ok ign:	-> true
	| `std.Err _:		-> false
	;;
}

const skipspace = {f
	while true
		match bio.peekc(f)
		| `std.Ok c:
			if !std.isspace(c)
				break
			;;
			bio.getc(f)
		| `std.Err e:		-> false
		;;
	;;
	-> true
}

/* Same as delim, but with special handling for '\n', '\r', and '\r\n' */
const readln = {f
	var ret, c

	ret = [][:]
	while true
		/* get at least delimiter count of characters */
		match ensureread(f, 1)
		| `std.Err `Eof:
			readinto(f, &ret, f.rend - f.rstart)
			if ret.len > 0
				-> `std.Ok ret
			else
				-> `std.Err `Eof
			;;
		| `std.Err e:	-> `std.Err e
		| `std.Ok _:
		;;
		/* scan for delimiter */
		for var i = f.rstart; i < f.rend; i++
			c = (f.rbuf[i] : char)
			if c == '\r' || c == '\n'
				readinto(f, &ret, i - f.rstart)
				f.rstart++
				/* if we have '\r', we can get '\r\n'. */
				if c == '\r' && unwrapc(peekc(f), -1) == '\n'
					f.rstart++
				;;
				-> `std.Ok ret
			;;
:nextitergetln
		;;
		readinto(f, &ret, f.rend - f.rstart)
	;;
	std.die("unreachable")
}

const unwrapc = {cc, v
	match cc
	| `std.Ok c:	-> c
	| _:	-> v
	;;
}

const readdelim = {f, delim, drop
	var ret

	ret = [][:]
	while true
		match ensureread(f, delim.len)
		| `std.Err `Eof:
			/* 
			 * We tried to get a delimiter, but came short.
			 * Return the whole end of the buffer as the
			 * read value, as though there was a terminating
			 * delimiter at the end. If we're at 0 bytes even
			 * then, return an eof.
			 */
			if drop
				f.rstart += f.rend - f.rstart
			else
				readinto(f, &ret, f.rend - f.rstart)
			;;
			match ret.len
			| 0:	-> `std.Err `Eof
			| _:	-> `std.Ok ret
			;;
		| `std.Err e:	-> `std.Err e
		| `std.Ok _:	/* nothing: scan the buffer */
		;;
		for var i = f.rstart; i < f.rend - delim.len; i++
			for var j = 0; j < delim.len; j++
				if f.rbuf[i + j] != delim[j]
					goto nextiterread
				;;
			;;
			if !drop
				readinto(f, &ret, i - f.rstart)
			else
				f.rstart += i - f.rstart
			;;
			f.rstart += delim.len
			-> `std.Ok ret
:nextiterread
		;;
		if !drop
			readinto(f, &ret, f.rend - f.rstart)
		else
			f.rstart += f.rend - f.rstart
		;;
	;;
	std.die("unreachable")
}

/*
Same as std.put, but buffered. Returns the number of bytes written.

FIXME: depends on std.fmt() having a flush buffer API. Until then,
we're stuck with a small static buffer.
*/
const put = {f, fmt, args
	var sl, ap, n

	ap = std.vastart(&args)
	sl = std.fmtv(fmt, &ap)
	n = write(f, sl)
	std.slfree(sl)
	-> n
}

const putv = {f, fmt, ap
	var sl, n

	sl = std.fmtv(fmt, ap)
	n = write(f, sl)
	std.slfree(sl)
	-> n
}

/* 
reads n bytes from the read buffer onto the heap-allocated slice
provided.
*/
const readinto = {f, bufp, n
	std.assert(f.rstart + n <= f.rend, "Reading too much from buffer")
	std.sljoin(bufp, f.rbuf[f.rstart:f.rstart + n])
	f.rstart += n
}

/* makes sure we can bufferedly write at least n bytes */
const ensurewrite = {f, n
	std.assert(n < f.wbuf.len, "ensured write capacity > buffer size")
	if n > f.wbuf.len - f.wend
		match writebuf(f, f.wbuf[:f.wend])
		| `std.Ok len:
			f.wend = 0
			-> `std.Ok len
		| `std.Err e: -> `std.Err e
		;;
	;;
	-> `std.Ok n
}

/*
makes sure we have at least n bytes buffered. returns true if we succeed
in buffering n bytes, false if we fail.
*/
const ensureread = {f, n
	var held

	std.assert(n < f.rbuf.len, "ensured read capacity > buffer size")
	held = f.rend - f.rstart
	if n > held
		match fill(f, n)
		| `std.Err e:	-> `std.Err e
		| `std.Ok len:
			if len >= n
				-> `std.Ok len
			else
				-> `std.Err `Eof
			;;
		;;
	else
		-> `std.Ok n
	;;
}

/* blats a buffer to an fd */
const writebuf = {f, src
	var count

	count = 0
	while src.len != 0
		match f.write(src)
		| `std.Ok 0:
			-> `std.Err `Eof
		| `std.Ok n:
			count += n
			src = src[n:]
		| `std.Err e:
			-> `std.Err errtype(e)
		;;
	;;
:writedone
	-> `std.Ok count
}



/*
Reads as many bytes as possible from the file into
the read buffer.
*/
const fill = {f, min
	var count, cap

	count = 0
	/* Clear the error state so we can retry */
	if f.lasterr != 0
		-> `std.Err geterr(f)
	;;

	/* if we need to shift the slice down to the start, do it */
	cap = f.rend - f.rstart
	if min > cap
		std.slcp(f.rbuf[:cap], f.rbuf[f.rstart:f.rend])
		f.rstart = 0
		f.rend = cap
	;;
	while count < min
		/*
		If we've already read data, we don't want to
		throw it away, so we report a successful short
		read, and then error on the next read.
		*/
		match f.read(f.rbuf[f.rend:])
		| `std.Ok 0:
			break
		| `std.Ok n:
			count += n
			f.rend += n
		| `std.Err e:
			if count > 0
				f.lasterr = e
			else
				-> `std.Err errtype(e)
			;;
			break
		;;
	;;

	if count == 0
		-> `std.Err `Eof
	else
		-> `std.Ok count
	;;
}

const geterr = {f
	var e

	e = f.lasterr
	f.lasterr = 0
	-> errtype(e)
}

const errtype = {e : std.errno -> err
	var errno

	errno = (e : std.errno)
	if errno == std.Ebadf
		-> `Ebadf
	elif errno == std.Einval
		-> `Ebadf
	elif errno == std.Efault
		-> `Eio
	else
		-> `Eio
	;;
}