summaryrefslogtreecommitdiff
path: root/lib/regex/redump.myr
blob: 7233864b2b4b058308669cb417cc3865cf043a92 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
use std
use bio
use regex

const main = {args
	var cmd, comp
	var verbose
	var fd

	verbose = false
	cmd = std.optparse(args, &[
		.argdesc = "regex [inputs...]",
		.minargs = 1,
		.maxargs = 1,
		.opts = [
			[.opt='v', .desc="dump verbose regex output"]
		][:],
	])
	for opt in cmd.opts
		match opt
		| ('v', _):	verbose = true
		| _:	std.fatal("Unknown argument")
		;;
	;;
	if verbose
		comp = regex.dbgcompile(cmd.args[0])
	else
		comp = regex.compile(cmd.args[0])
	;;
	match comp
	| `std.Fail m:	
		std.fatal("unable to compile regex: {}\n", regex.failmsg(m))
	| `std.Ok re:
		if cmd.args.len > 1
			runall(re, cmd.args)
		else
			fd = bio.mkfile(0, bio.Rd)
			dump(re, fd)
			bio.close(fd)
		;;
	;;
}

const runall = {re, files

	for f in files
		match bio.open(f, bio.Rd)
		| `std.Ok fd:
			dump(re, fd)
			bio.close(fd)
		| `std.Fail m:
			std.fatal("failed to open {}: {}\n", f, m)
		;;
	;;
}

const dump = {re, fd 
	while true
		match bio.readln(fd)
		| `std.Some ln:
			show(re, ln, regex.exec(re, ln))
			std.slfree(ln)
		| `std.None:
			break
		;;
	;;
}

const show = {re, ln, mg
	var i

	match mg
	| `std.Some rl:
		std.put("Matched: {}\n", rl[0])
		for i = 1; i < rl.len; i++
			std.put("\tgroup {}: {}\n", i, rl[i])
		;;
	| `std.None:
		std.put("Match failed:\n")
		std.put("\t{}\n", ln)
		std.put("\t")
		for i = 0; i < re.strp - 1; i++
			std.put("~")
		;;
		std.put("^\n")
	;;
}