summaryrefslogtreecommitdiff
path: root/lib/std/execvp.myr
blob: 38d9fc5d9603708be2b6aeaa086010096e759c68 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
use "alloc.use"
use "env.use"
use "fmt.use"
use "option.use"
use "strfind.use"
use "strsplit.use"
use "syswrap.use"

pkg std = 
	const execvp	: (cmd : byte[:], args : byte[:][:] -> int64)
	const execvpe	: (cmd : byte[:], args : byte[:][:], env : byte[:][:] -> int64)
;;

const execvp = {cmd, args
	var paths, binpath
	var buf : byte[512]

	match strfind(cmd, "/")
	| `Some _:
		-> execv(cmd, args)
	| `None:
		paths = getpaths()
		for p in paths
			binpath = bfmt(buf[:], "{}/{}", p, cmd)
			execv(binpath, args)
		;;
		slfree(paths)
	;;
	-> -1
}

const execvpe = {cmd, args, env
	var paths, binpath
	var buf : byte[512]

	match strfind(cmd, "/")
	| `Some _:
		-> execve(cmd, args, env)
	| `None:
		paths = getpaths()
		for p in paths
			binpath = bfmt(buf[:], "{}/{}", p, cmd)
			execve(binpath, args, env)
		;;
		slfree(paths)
	;;
	-> -1
}

const getpaths = {
	var path
	match getenv("PATH")
	| `Some p:	path = p
	| `None:	path = "/usr/local/bin:/bin:/usr/bin"
	;;
	-> strsplit(path, ":")
}