summaryrefslogtreecommitdiff
path: root/lib/std/execvp.myr
blob: f6696e30044abeb3a881c787d20fef293864b0fa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
use "alloc"
use "env"
use "errno"
use "fmt"
use "option"
use "strfind"
use "strsplit"
use "syswrap"

pkg std = 
	const execvp	: (cmd : byte[:], args : byte[:][:] -> errno)
	const execvpe	: (cmd : byte[:], args : byte[:][:], env : byte[:][:] -> errno)
;;

const execvp = {cmd, args
	var paths, binpath
	var buf : byte[512]

	match strfind(cmd, "/")
	| `Some _:
		-> execv(cmd, args)
	| `None:
		paths = getpaths()
		for p : paths
			binpath = bfmt(buf[:], "{}/{}", p, cmd)
			execv(binpath, args)
		;;
		slfree(paths)
	;;
	-> -1
}

const execvpe = {cmd, args, env
	var paths, binpath
	var buf : byte[512]

	match strfind(cmd, "/")
	| `Some _:
		-> execve(cmd, args, env)
	| `None:
		paths = getpaths()
		for p : paths
			binpath = bfmt(buf[:], "{}/{}", p, cmd)
			execve(binpath, args, env)
		;;
		slfree(paths)
	;;
	-> -1
}

const getpaths = {
	var path
	match getenv("PATH")
	| `Some p:	path = p
	| `None:	path = "/usr/local/bin:/bin:/usr/bin"
	;;
	-> strsplit(path, ":")
}