summaryrefslogtreecommitdiff
path: root/lib/std/getint.myr
blob: 4445c4ad586b26dc015664c5a201457800e1ff6e (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
use "die"
use "memops"

pkg std =
	generic gethost64	: (buf : byte[:]	-> @a::(numeric,integral))
	generic getle64		: (buf : byte[:]	-> @a::(numeric,integral))
	generic getbe64		: (buf : byte[:]	-> @a::(numeric,integral))
	generic gethost32	: (buf : byte[:]	-> @a::(numeric,integral))
	generic getle32		: (buf : byte[:]	-> @a::(numeric,integral))
	generic getbe32		: (buf : byte[:]	-> @a::(numeric,integral))
	generic gethost16	: (buf : byte[:]	-> @a::(numeric,integral))
	generic getle16		: (buf : byte[:]	-> @a::(numeric,integral))
	generic getbe16		: (buf : byte[:]	-> @a::(numeric,integral))
	generic gethost8	: (buf : byte[:]	-> @a::(numeric,integral))
	generic getle8		: (buf : byte[:]	-> @a::(numeric,integral))
	generic getbe8		: (buf : byte[:]	-> @a::(numeric,integral))
;;

generic gethost64 = {buf -> @a::(numeric,integral)
	var val : int64
	iassert(buf.len >= 8, "gethost64: index out of bounds")
	memblit((&val : byte#), (buf : byte#), 8)
	-> (val : @a::(numeric,integral))
}

generic getbe64 = {buf -> @a::(numeric,integral)
	-> ((buf[0] : @a::(numeric,integral)) << 56) | \
		((buf[1] : @a::(numeric,integral)) << 48) | \
		((buf[2] : @a::(numeric,integral)) << 40) | \
		((buf[3] : @a::(numeric,integral)) << 32) | \
		((buf[4] : @a::(numeric,integral)) << 24) | \
		((buf[5] : @a::(numeric,integral)) << 16) | \
		((buf[6] : @a::(numeric,integral)) << 8) | \
		((buf[7] : @a::(numeric,integral)) << 0)
}

generic getle64 = {buf
	-> ((buf[0] : @a::(numeric,integral))  << 0) | \
		((buf[1] : @a::(numeric,integral))  << 8) | \
		((buf[2] : @a::(numeric,integral))  << 16) | \
		((buf[3] : @a::(numeric,integral))  << 24) | \
		((buf[4] : @a::(numeric,integral))  << 32) | \
		((buf[5] : @a::(numeric,integral))  << 40) | \
		((buf[6] : @a::(numeric,integral))  << 48) | \
		((buf[7] : @a::(numeric,integral))  << 56)
}

generic gethost32 = {buf -> @a::(numeric,integral)
	var val : int32
	iassert(buf.len >= 4, "gethost32: index out of bounds")
	memblit((&val : byte#), (buf : byte#), 4)
	-> (val : @a::(numeric,integral))
}

generic getbe32 = {buf
	-> ((buf[0] : @a::(numeric,integral)) << 24) | \
		((buf[1] : @a::(numeric,integral)) << 16) | \
		((buf[2] : @a::(numeric,integral)) << 8) | \
		((buf[3] : @a::(numeric,integral)) << 0)
}

generic getle32 = {buf
	-> ((buf[0] : @a::(numeric,integral)) << 0) | \
		((buf[1] : @a::(numeric,integral)) << 8) | \
		((buf[2] : @a::(numeric,integral)) << 16) | \
		((buf[3] : @a::(numeric,integral)) << 24)
}

generic gethost16 = {buf -> @a::(numeric,integral)
	var val : int16
	iassert(buf.len >= 2, "gethost16: index out of bounds")
	memblit((&val : byte#), (buf : byte#), 4)
	-> (val : @a::(numeric,integral))
}

generic getbe16 = {buf
	-> ((buf[0] : @a::(numeric,integral)) << 8) | \
		((buf[1] : @a::(numeric,integral)) << 0)
}

generic getle16 = {buf
	-> ((buf[0] : @a::(numeric,integral)) << 0) | \
		((buf[1] : @a::(numeric,integral)) << 8)
}

generic gethost8 = {buf
	-> (buf[0] : @a::(numeric,integral)) << 0
}

generic getbe8 = {buf
	-> (buf[0] : @a::(numeric,integral)) << 0
}

generic getle8 = {buf
	-> (buf[0] : @a::(numeric,integral)) << 0
}