summaryrefslogtreecommitdiff
path: root/lib/std/memops-impl.myr
blob: 67c67d330c7dadff2bf17af3fce5f79759888bec (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
use "types"

pkg std =
	pkglocal const memblit	: (dst : byte#, src : byte#, len : std.size -> void)
	pkglocal const memfill	: (dst : byte#, val : byte, len : std.size -> void)
	pkglocal const memeq	: (a : byte#, b : byte#, len : std.size -> bool)
;;


const memblit = {dst, src, len
	var sa, da
	var s, d

	da = (dst : intptr)
	sa = (src : intptr)
	d = dst[:len]
	s = src[:len]

	if da == sa
		-> void
	elif da < sa
		for var i = 0; i < d.len; i++
			d[i] = s[i]
		;;
	else
		for var i = d.len; i > 0; i--
			d[i - 1] = s[i - 1]
		;;
	;;
}

const memfill = {dst, val, len
	var d

	d = dst[:len]
	for var i = 0; i < d.len; i++
		d[i] = val
	;;
}

const memeq = {a, b, len
	var sa, sb

	sa = a[:len]
	sb = b[:len]
	for i = 0; i < len; i++
		if sa[i] != sb[i]
			-> false
		;;
	;;
	-> true
}