summaryrefslogtreecommitdiff
path: root/lib/std/resolve+posixy.myr
blob: 8fa83525f2ac8da100db1bc80af9a7d3e5f6017d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
use sys
use "alloc"
use "chartype"
use "die"
use "endian"
use "extremum"
use "hashfuncs"
use "htab"
use "ipparse"
use "now"
use "option"
use "result"
use "slcp"
use "sldup"
use "sleq"
use "slpush"
use "slurp"
use "strfind"
use "strsplit"
use "strstrip"
use "threadhooks"
use "types"
use "utf"

use "fmt"

pkg std =
	type rectype = union
		`DnsA		/* host address */
		`DnsNS		/* authoritative name server */
		`DnsCNAME	/* canonical name for an alias */
		`DnsSOA		/* marks the start of a zone of authority */
		`DnsWKS		/* well known service description */
		`DnsPTR		/* domain name pointer */
		`DnsHINFO	/* host information */
		`DnsMINFO	/* mailbox or mail list information */
		`DnsMX		/* mail exchange */
		`DnsTXT		/* text strings */
		`DnsAAAA	/* ipv6 host address */
		`DnsInval	/* invalid */
	;;

	type resolveerr = union
		`Timeout
		`Badconn
		`Badhost
		`Badsrv
		`Badquery
		`Badresp
	;;

	type hostinfo = struct
		fam	: sys.sockfam
		stype	: sys.socktype
		ttl	: uint32
		addr	: netaddr
		stale	: time
	;;

	const resolve	: (host : byte[:]	-> result(hostinfo[:], resolveerr))
	const resolvemx	: (host : byte[:]	-> result(hostinfo[:], resolveerr))
	const resolverec	: (host : byte[:], t : rectype	-> result(hostinfo[:], resolveerr))
;;

const Hostfile = "/etc/hosts"
const Resolvfile = "/etc/resolv.conf"
const Timeout = 2_000

var hostmap	: htab(byte[:], hostinfo)#
var dnscache	: htab(byte[:], hostinfo)#
var search	: byte[:][:]
var nameservers	: netaddr[:]

const __init__ = {
	hostmap = mkht(strhash, streq)
	dnscache = mkht(strhash, streq)
	loadhosts()
	loadresolv()
}

const resolve = {host
	/*TODO: v4 and v6 */
	-> resolverec(host, `DnsA)
}

const resolvemx = {host
	-> resolverec(host, `DnsMX)
}

const resolverec = {host, t
	match hostfind(host)
	| `Some hinf:
		-> `Ok sldup([hinf][:])
	| `None:
		-> dnsresolve(host, rectype(t))
	;;
}

const hostfind = {host
	var h
	lock(netlck)
	match htget(dnscache, host)
	| `std.Some inf:
		if inf.stale > std.now()
			h = `std.Some inf
		else
			h = htget(hostmap, host)
		;;
	| `std.None:
		h = htget(hostmap, host)
	;;
	unlock(netlck)
	-> h
}

const loadhosts = {
	var h
	var lines

	match slurp(Hostfile)
	| `Ok d:	h = d
	| `Err m:	-> void
	;;

	lines = strsplit(h, "\n")
	for l : lines
		/* trim comment */
		match strfind(l, "#")
		| `Some idx:	l = l[:idx]
		| `None:	/* whole line */
		;;

		match word(l)
		| `Some (ip, rest):
			match ipparse(ip)
			| `Some addr:
				lock(netlck)
				addhosts(addr, ip, rest)
				unlock(netlck)
			| `None:
				/*
				invalid addresses are ignored: we don't want to break stuff
				with invalid or unsupported addresses
				*/
				
			;;
		| `None:
		;;
	;;
	slfree(lines)
	slfree(h)
}

const addhosts = {addr, as, str
	var hinf
	var fam

	match addr
	| `Ipv4 _:	fam = sys.Afinet
	| `Ipv6 _:	fam = sys.Afinet6
	;;
	while true
		match word(str)
		| `Some (name, rest):
			str = rest
			if hthas(hostmap, name)
				continue
			;;
			hinf = [
				.fam=fam,
				.stype = 0,
				.ttl = 0,
				.addr = addr
			]
			htput(hostmap, sldup(name), hinf)
		| `None:
			-> void
		;;
	;;
}

const loadresolv = {
	var h
	var lines

	lock(netlck)
	match slurp(Resolvfile)
	| `Ok d:	h = d
	| `Err m:	-> void
	;;

	lines = strsplit(h, "\n")
	for l : lines
		match strfind(l, "#")
		| `Some _idx: l = l[:_idx]
		| `None:
		;;

		match word(l)
		| `Some ("nameserver", srv):
			addns(srv)
		| `Some (_, rest):
			/* invalid or unrecognized commands */
		| `None:
			/* unrecognized lines */
		;;
	;;
	slfree(lines)
	slfree(h)
	unlock(netlck)
}

const addns = {rest
	match word(rest)
	| `Some (name, _):
		match ipparse(name)
		| `Some addr: 
			slpush(&nameservers, addr)
		| `None:
			/* nothing */
		;;
	| `None:
		/* nothing */
	;;
}

const word = {s
	var c, len

	len = 0
	s = strfstrip(s)
	for c = decode(s[len:]); c != Badchar && !isblank(c); c = decode(s[len:])
		len += charlen(c)
	;;
	if len == 0
		-> `None
	else
		-> `Some (s[:len], s[len:])
	;;
}


const dnsresolve = {host, rt
	var nsrv, r

	if !valid(host)
		-> `Err (`Badhost)
	;;
	/* FIXME: Assumption: nameservers is not modified by other threads */
	for ns : nameservers
		nsrv = dnsconnect(ns)
		if nsrv >= 0
			r = dnsquery(nsrv, host, rt)
			sys.close(nsrv)
			-> r
		;;
	;;
	-> `Err (`Badsrv)
}

const dnsconnect = {ns
	match ns
	| `Ipv4 addr:	-> dnsconnectv4(addr)
	| `Ipv6 addr:	die("don't support ipv6 yet\n")
	;;
}

const dnsconnectv4 = {addr
	var sa : sys.sockaddr_in
	var s
	var status

	s = sys.socket(sys.Afinet, sys.Sockdgram, 0)
	if s < 0
		-> -1
	;;
	sa = [
		.fam = sys.Afinet,
		.port = hosttonet(53),
		.addr = addr,
	]
	status = sys.connect(s, (&sa : sys.sockaddr#), sizeof(sys.sockaddr_in))
	if status < 0
		-> -1
	;;
	-> s
}

const dnsquery = {srv, host, t
	var id

	id = tquery(srv, host, t)
	-> rquery(srv, host, id)
}

const Qr : uint16 = 1 << 0
const Aa : uint16 = 1 << 5
const Tc : uint16 = 1 << 6
const Rd : uint16 = 1 << 7
const Ra : uint16 = 1 << 8

var nextid : uint16 = 42
const tquery = {srv, host, t
	var pkt : byte[512] /* big enough */
	var off : size

	/* header */
	off = 0
	nextid++
	off += pack16(pkt[:], off, nextid)	/* id */
	off += pack16(pkt[:], off, Ra)	/* flags */
	off += pack16(pkt[:], off, 1)	/* qdcount */
	off += pack16(pkt[:], off, 0)	/* ancount */
	off += pack16(pkt[:], off, 0)	/* nscount */
	off += pack16(pkt[:], off, 0)	/* arcount */

	/* query */
	off += packname(pkt[:], off, host)	/* host */
	off += pack16(pkt[:], off, (t : uint16)) /* qtype: a record */
	off += pack16(pkt[:], off, 0x1) /* qclass: inet4 */

	sys.write(srv, pkt[:off])
	-> nextid
}

const rquery = {srv, host, id
	var pktbuf : byte[1024]
	var pkt, pfd, giveup
	var r, n, inf

	giveup = std.now() + 1000*Timeout
:again
	pfd = [
		[.fd=srv, .events=sys.Pollin, .revents=0]
	][:]
	r = sys.poll(pfd[:], (giveup - std.now() : int)/1000)
	if r < 0
		-> `Err `Badconn
	elif r == 0
		-> `Err `Timeout
	else
		n = sys.read(srv, pktbuf[:])
		if n < 0
			-> `Err `Badconn
		;;
		pkt = pktbuf[:n]
		inf = hosts(pkt, host, id)
		match inf
		| `std.Err `Badresp:
			goto again
		| _:	
			-> inf
		;;
	;;
}

const hosts = {pkt, host, id
	var off, ni
	var r, n, q, a, t, ttl
	var hinf : hostinfo[:]
	var v6dat : byte[16]

	off = 0
	/* parse header */
	(r, off) = unpack16(pkt, off)	/* id */
	if r != id
		-> `Err `Badresp
	;;
	(_, off) = unpack16(pkt, off)	/* flags */
	(q, off) = unpack16(pkt, off)	/* qdcount */
	(a, off) = unpack16(pkt, off)	/* ancount */
	(_, off) = unpack16(pkt, off)	/* nscount */
	(_, off) = unpack16(pkt, off)	/* arcount */

	/* skip past query records */
	for var i = 0; i < q; i++
		off = skipname(pkt, off)	/* name */
		(_, off) = unpack16(pkt, off)	/* type */
		(_, off) = unpack16(pkt, off)	/* class */
	;;

	/* parse answer records */
	ni = 0
	hinf = slalloc((a : size))
	for var i = 0; i < a; i++
		off = skipname(pkt, off)	/* name */
		(t, off) = unpack16(pkt, off)	/* type */
		(_, off) = unpack16(pkt, off)	/* class */
		(ttl, off) = unpack32(pkt, off)	/* ttl */
		(n, off) = unpack16(pkt, off)	/* rdatalen */

		hinf[ni].ttl = ttl
		hinf[ni].stale = (ttl * 1_000_000 : time) + std.now()
		match id2type(t)
		| `DnsA:
			/* the thing we're interested in: our IP address */
			hinf[ni].addr = `Ipv4 [pkt[off], pkt[off+1], pkt[off+2], pkt[off+3]]
			off += 4;
			ni++
		| `DnsAAAA:
			std.slcp(v6dat[:], pkt[off:off+16])
			hinf[ni].addr = `Ipv6 v6dat
			off += 16
			ni++
		| _:
			off += (n : std.size)
		;;
	;;
	lock(netlck)
	if ni != 0 && hinf[0].ttl != 0
		std.htput(dnscache, std.sldup(host), hinf[0])
	;;
	unlock(netlck)
	-> `Ok hinf[:ni]
}


const skipname = {pkt, off
	var sz

	for sz = (pkt[off] : size); sz != 0; sz = (pkt[off] : size)
		/* ptr is 2 bytes */
		if sz & 0xC0 == 0xC0
			-> off + 2
		else
			off += sz + 1
		;;
	;;
	-> off + 1
}


const pack16 = {buf, off, v
	buf[off]	= ((v & 0xff00) >> 8 : byte)
	buf[off+1]	= ((v & 0x00ff) >> 0 : byte)
	-> sizeof(uint16) /* we always write one uint16 */
}

const unpack16 = {buf, off
	var v

	v = 0
	v |= (buf[off + 0] : uint16) << 8
	v |= (buf[off + 1] : uint16) << 0
	-> (v, off+sizeof(uint16))
}

const unpack32 = {buf, off
	var v

	v = (buf[off] : uint32) << 24
	v |= (buf[off+1] : uint32) << 32
	v |= (buf[off+2] : uint32) << 8
	v |= (buf[off+3] : uint32)
	-> (v, off+sizeof(uint32))
}

const packname = {buf, off : size, host
	var start
	var last

	start = off
	last = 0
	for var i = 0; i < host.len; i++
		if host[i] == ('.' : byte)
			off += addseg(buf, off, host[last:i])
			last = i + 1
		;;
	;;
	if host[host.len - 1] != ('.' : byte)
		off += addseg(buf, off, host[last:])
	;;
	off += addseg(buf, off, "") /* null terminating segment */
	-> off - start
}

const addseg = {buf, off, str
	buf[off] = (str.len : byte)
	slcp(buf[off + 1 : off + str.len + 1], str)
	-> str.len + 1
}

const valid = {host : byte[:]
	var i
	var seglen

	/* maximum length: 255 chars */
	if host.len > 255
		-> false
	;;

	seglen = 0
	for i = 0; i < host.len; i++
		if host[i] == ('.' : byte)
			seglen = 0
		;;
		if seglen > 63
			-> false
		;;
		if host[i] & 0x80 != 0
			-> false
		;;
	;;

	-> true
}

const id2type = {rtype
	match rtype
	| 1:	-> `DnsA
	| 2:	-> `DnsNS
	| 5:	-> `DnsCNAME
	| 6:	-> `DnsSOA
	| 11:	-> `DnsWKS
	| 12:	-> `DnsPTR
	| 13:	-> `DnsHINFO
	| 14:	-> `DnsMINFO
	| 15:	-> `DnsMX
	| 16:	-> `DnsTXT
	| 28:	-> `DnsAAAA
	| _:	-> `DnsInval
	;;
}

const rectype = {rtype
	match rtype
	| `DnsA:	-> 1  /* host address */
	| `DnsNS:	-> 2  /* authoritative name server */
	| `DnsCNAME:	-> 5  /* canonical name for an alias */
	| `DnsSOA:	-> 6  /* marks the start of a zone of authority */
	| `DnsWKS:	-> 11 /* well known service description */
	| `DnsPTR:	-> 12 /* domain name pointer */
	| `DnsHINFO:	-> 13 /* host information */
	| `DnsMINFO:	-> 14 /* mailbox or mail list information */
	| `DnsMX:	-> 15 /* mail exchange */
	| `DnsTXT:	-> 16 /* text strings */
	| `DnsAAAA:	-> 28 /* ipv6 host address */
	| `DnsInval:	-> -1
	;;
}