summaryrefslogtreecommitdiff
path: root/lib/std/search.myr
blob: 8e5e259abee6d43616f6a3ee2c47c4b865bb54aa (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
use "cmp"
use "option"
use "types"

pkg std =
	generic lsearch	: (sl : @t[:], key : @k, cmp : (v : @t, k : @k -> order) -> option(@idx)) :: integral,numeric @idx
	generic bsearch	: (sl : @t[:], key : @k, cmp : (v : @t, k : @k -> order) -> option(@idx)) :: integral,numeric @idx
;;

/* linear search over a list of values */
generic lsearch = {sl, key, cmp
	for var i = 0; i < sl.len; i++
		match cmp(sl[i], key)
		| `Equal:
			-> `Some i
		| _:
			/* nothing */
		;;
	;;
	-> `None
}

/* binary search over a sorted list of values. */
generic bsearch  = {sl, key, cmp
	var hi, lo, mid : size

	lo = 0
	hi = sl.len - 1

	while lo <= hi
		mid = (hi + lo) / 2
		match cmp(sl[mid], key)
		| `After:	hi = mid - 1
		| `Before:	lo = mid + 1
		| `Equal:	-> `Some (mid : @idx)
		;;
	;;
	-> `None
}