summaryrefslogtreecommitdiff
path: root/lib/std/strfind.myr
blob: f446f69b079edf96cf77258acd44449f56602b22 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
use "types"
use "option"

pkg std =
	const strfind	: (haystack : byte[:], needle : byte[:] -> option(size))
	const strrfind	: (haystack : byte[:], needle : byte[:] -> option(size))
	const strhas	: (haystack : byte[:], needle : byte[:]	-> bool)
;;

const strfind = {haystack, needle
	-> strfindin(haystack, needle, 0, haystack.len, 1)
}

const strrfind = {haystack, needle
	-> strfindin(haystack, needle, haystack.len - 1, -1, -1)
}

const strfindin = {haystack, needle, start, end, inc
	if haystack.len == 0 && needle.len == 0
		-> `std.Some 0
	;;
	for var i = start; i != end; i += inc
		/* 
		if we knew the direction we could terminate early,
		but we allow the start and end to be passed in.
		*/
		if i + needle.len > haystack.len
			continue
		;;
		for var j = 0; j < needle.len; j++
			if haystack[i + j] != needle[j]
				goto nextiter
			;;
		;;
		-> `Some i
:nextiter
	;;
	-> `None
}

const strhas = {haystack, needle
	match strfind(haystack, needle)
	| `Some _:	-> true
	| `None:	-> false
	;;
}