summaryrefslogtreecommitdiff
path: root/lib/sys/syscall+openbsd-x64.s
blob: ea4a9b796b67ee113436a8ae19d360a499014f25 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
.globl sys$syscall
sys$syscall:
	/*
	hack: We load 6 args regardless of
	how many we actually have. This may
	load junk values, but if the syscall
	doesn't use them, it's going to be
	harmless.
	*/
	movq %rdi,%rax
	/* 8(%rsp): hidden type arg */
	movq 16(%rsp),%rdi
	movq 24(%rsp),%rsi
	movq 32(%rsp),%rdx
	movq 40(%rsp),%r10
	movq 48(%rsp),%r8
	movq 56(%rsp),%r9

	syscall
	jae .success
	negq %rax

.success:
	ret

/* __tfork_thread(tfp : tforkparams#, sz : size, fn : void#, arg : void#-> tid) */
.globl sys$__tfork_thread
sys$__tfork_thread:
	/* syscall */
	movq	%rdx, %r8
	movq	%rcx, %r9
	movq	$8, %rax
	syscall
	jb	.failparent

	/* are we in the parent? */
	cmpq	$0,%rax
	jnz	.doneparent

	/* call the function and __threxit */
	movq	%r9, %rdi
	callq	*%r8

	movq	$302,%rax
	xorq	%rdi,%rdi
	syscall

.failparent:
	negq	%rax

.doneparent:
	ret